From b06990293397d4b6d0374097f09d1cc5679216e3 Mon Sep 17 00:00:00 2001
From: hybrid <hybrid@hybridlabs.pro>
Date: Thu, 11 Jun 2026 19:55:04 +0300
Subject: init

---
 Client/Client_EndGame.sqf | 67 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 Client/Client_EndGame.sqf

(limited to 'Client/Client_EndGame.sqf')

diff --git a/Client/Client_EndGame.sqf b/Client/Client_EndGame.sqf
new file mode 100644
index 0000000..e6ccb0f
--- /dev/null
+++ b/Client/Client_EndGame.sqf
@@ -0,0 +1,67 @@
+Private ['_HQ','_base','_blist','_camShotOrder','_camera','_nvgstate','_position','_secTarget','_side','_track','_vehi'];
+
+_side = _this select 0;
+_blist = _this select 1;
+
+[_side] ExecVM "Client\GUI\GUI_EndOfGameStats.sqf";
+//_track = if (WF_A2_Vanilla) then {"Track21_Rise_Of_The_Fallen"} else {"EP1_Track15"}; //---old
+_track = if (WF_A2_Vanilla) then {["Track21_Rise_Of_The_Fallen",41]} else {["EP1_Track13",91]}; //---changed-MrNiceGuy
+playMusic _track;
+_base = WestMHQ;
+_secTarget = EastMHQ;
+if (_side == West) then {_base = EastMHQ;_secTarget = WestMHQ};
+_position = getPos _base;
+
+_blist = [_secTarget,_blist] Call SortByDistance;
+_blist = [_secTarget] + _blist;
+
+//--- Safety Pos.
+_HQ = (sideJoinedText) Call GetSideHQ;
+_vehi = vehicle player;
+if (_vehi != player) then {player action ["EJECT", _vehi];_vehi = player};
+_vehi setVelocity [0,0,-0.1];
+_vehi setPos ([getPos _HQ,20,30] Call GetRandomPosition);
+
+if (!isNil "DeathCamera") then {
+	DeathCamera cameraEffect["TERMINATE","BACK"];
+	camDestroy DeathCamera;
+	"colorCorrections" ppEffectEnable false;
+	"dynamicBlur" ppEffectEnable false;
+};
+
+_camera = "camera" camCreate _position;
+_camera camSetDir 0;
+_camera camSetFov 0.200;
+_camera cameraEffect["Internal","back"];
+_camera camSetTarget getPos _base;
+_camera camSetRelPos [160.80,130.29,140.07];
+_camera camCommit 0;
+_nvgstate = if (daytime > 18.5 || daytime < 5.5) then {true} else {false};
+camUseNVG _nvgstate;
+
+waitUntil {camCommitted _camera};
+
+_camera camSetRelPos [-190.71,190.55,180.94];
+_camera camCommit 10;
+
+waitUntil {camCommitted _camera};
+
+_camShotOrder = [[0,100,35],[50,0,20],[0,-50,20],[-50,0,20]];
+
+{
+	_camera camSetPos getPos _x;
+	_camera camSetTarget getPos _x;
+	
+	{
+		_camera camSetRelPos _x;
+		_camera camCommit 5;
+		waitUntil {camCommitted _camera};
+	} forEach _camShotOrder;
+	
+	_camera camSetRelPos [0,100,35];
+	_camera camCommit 5;
+	waitUntil {camCommitted _camera};
+} forEach _blist;
+
+sleep 3;
+failMission "END1";
\ No newline at end of file
-- 
cgit v1.3.1